@echo off
title Jai Computers - Windows Slow / Hang Safe Cleanup
color 0A
echo Jai Computers Osian - Windows Slow / Hang Safe Cleanup
echo Phone: +91 7300066900
echo.
net session >nul 2>&1
if not "%errorlevel%"=="0" (
  echo Admin permission required. UAC prompt open ho raha hai...
  powershell -NoProfile -ExecutionPolicy Bypass -Command "Start-Process -FilePath '%~f0' -Verb RunAs"
  exit /b
)
echo Admin mode: OK
echo.
echo IMPORTANT: Ye script software cleanup aur health check ke liye hai.
echo Hardware fault, bad SSD/RAM, heating ya motherboard issue isse repair nahi hoga.
echo.
echo Recommended: Right click karke "Run as administrator" karein.
echo.
pause
set "LOG=%USERPROFILE%\Desktop\JaiComputers_Slow_PC_Report.txt"
echo Jai Computers Slow PC Report > "%LOG%"
echo Date: %DATE% %TIME% >> "%LOG%"
echo. >> "%LOG%"
echo Basic system info collect ho raha hai...
systeminfo >> "%LOG%" 2>&1
echo. >> "%LOG%"
echo Running tasks: >> "%LOG%"
tasklist >> "%LOG%" 2>&1
echo.
choice /M "Temp files clean karna hai? Unsaved app data close kar dein"
if errorlevel 2 goto skiptemp
echo Temp files cleaning...
if defined TEMP if exist "%TEMP%\" (
  del /q /f "%TEMP%\*" 2>nul
  for /d %%D in ("%TEMP%\*") do rd /s /q "%%D" 2>nul
)
:skiptemp
echo.
echo Windows file health check start ho raha hai. Time lag sakta hai.
sfc /scannow
echo.
echo Storage settings open ho rahi hai. Startup apps aur C drive cleanup check karein.
start ms-settings:storagesense
start taskmgr
echo.
echo Report saved: %LOG%
echo Agar PC abhi bhi slow hai to SSD/RAM health check ke liye Jai Computers par WhatsApp karein.
pause